[译]Perl:使用__SUB__获得当前子程序的引用

原文:http://www.effectiveperlprogramming.com/blog/1503

如果你想要写一个递归的子程序,但你不知道当前子程序的名称,该怎么办?由于Perl是一门动态语言且Perl中的代码引用是第一类对象,就算一个代码引用有自己的名字,你也可能不知道它的名字. Perl 5.16引入了__SUB__ 作为一个能返回当前子程序引用的特殊序列.虽然不用这个新特性你也能使用其他模块实现几乎同样的功能,但那些模块都有一些你也许想要避免的缺点.

虽然__SUB__看起来和__FILE__, __LINE__,以及__PACKAGE__这些编译时指令类似,但其实不是,__SUB__的解析发生在运行时,所以你可以在随后定义的子程序中使用它.

首先,考虑一下在没有__SUB__特性的时候,你是怎么做的.你可能会声明一个变量用来保存子程序引用,然后在下一条语句中定义那个子程序.由于你已经声明了那个变量,所以你可以在子程序中使用它.虽然在定义的时候那个变量还不是引用,但也没关系,因为Perl只会在真正运行子程序的时候才会对它解引用:

use v5.10;
 
my $sub;
 
$sub = sub {
    state $count = 10;
    say $count;
    return if --$count < 0;
    $sub->();
    };
 
$sub->();

输出结果是一个倒数序列:

10
9
8
7
6
5
4
3
2
1
0

这种写法有两个限制:一个是代码引用必须存储在一个变量中,还有就是这个变量必须已经被定义.这种限制经常会带来一些不便.不仅如此,你的匿名子程序还包含了自身的引用,所以你需要使用弱引用的技巧否则就让这个引用一直存在下去.这两种结果都不是我们想要的.

Rafaël Garcia-Suarez解决了这个问题,它创建的Sub::Current模块可以给你提供一个ROUTINE函数,该函数会返回当前子程序的引用,即使该子程序是一个命名子程序:

use v5.10;
use Sub::Current;
 
sub countdown {
    state $count = 10;
    say $count;
    return if --$count < 0;
    ROUTINE->();
    };
 
countdown();

你也许想要把这样的代码引用定义为一条单独的语句,即使你不需要这么做.比如你想要把代码引用定义在参数列表中:

use v5.10;
use Sub::Current;
 
sub run { $_[0]->() };
 
run( sub {
        state $count = 10;
        say $count;
        return if --$count < 0;
        ROUTINE->();
        }
    );

你也许还需要把子程序作为返回值定义在一条语句中:

use v5.10;
use Sub::Current;
 
sub factory {
    my $start = shift;
    sub {
        state $count = $start;
        say $count;
        return if --$count < 0;
        ROUTINE->();
        }
    };
 
factory(4)->();

使用这个模块的缺点就是对CPAN的依赖,虽然它是个很轻量级的.还有另一个模块, Devel::Caller,由Richard Clamp编写.它可以获得调用栈中在任意层级的代码引用,包括当前层级:

use v5.10;
use Devel::Caller qw(caller_cv);
 
sub factory {
    my $start = shift;
    sub {
        state $count = $start;
        say $count;
        return if --$count < 0;
        caller_cv(0)->();
        }
    };
 
factory(7)->();

Perl 5.16可以让你实现相同的功能而不需要任何的CPAN模块:

use v5.15.6;  # until v5.16 is released
 
sub factory {
    my $start = shift;
    sub {
        state $count = $start;
        say $count;
        return if --$count < 0;
        __SUB__->();
        }
    };

和许多添加于Perl v5.10的新特性一样,你可以像上面的代码示例一样通过使用"use 版本号"这样的语句来开启__SUB__特性,你还可以使用"use feature"导入current_sub来实现同样的功能:

use feature qw(say state current_sub);
 
sub factory {
    my $start = shift;
    sub {
        state $count = $start;
        say $count;
        return if --$count < 0;
        __SUB__->();
        }
    };
 
factory(7)->();

需要记住的东西:

• Perl v5.16提供了__SUB__指令,可以返回当前运行的子程序的引用.
• 可以通过指定Perl版本或者通过use feature来开启该特性.
• 在Perl v5.16之前的版本中,你可以使用Sub::Current来实现同样的功能.