VB刷网页程序，VB+DOS

本来以为用VB刷一个链接是很简单的，但实际操作时，遇到了一个BUG！那就是IE内核的浏览器内存泄漏问题。在VB中的表现是：用web控件不停点击或者刷新一个链接时，内存会不断的积累，即使你释放了所有对象，关闭了所有弹出的页面，只要主web控件不关闭，内存会积累到惊人的地步（因为web控件用的是IE内核）于是我上网寻求解决办法，结果没有发现巨人，得到的回答只有一个：等微软解决吧！

但也有人说可以在执行一段时间后重启程序以释放内存。我想这是我能力范围内最好的办法了！

怎么重启呢？？试想一个用户正在使用你的程序，可他突然消失了，无法让人接受！其次，如果你的程序最小化时，重启时会不会给用户造成骚扰？怎么使程序保持安静？

综合以上的问题，我的解决办法是：用两个exe程序，一个作为主程序，一个作为点击网页的服务程序（不可见），他们之间的数据交互通过注册表实现。

这样的好处是，在不知不觉中完成点击，重启服务程序用户根本感觉不到；其次是这样可以大大减小主程序的压力，如果让主程序点击网页会使程序很卡，这样完全释放了主程序，它的任务只是接收注册表数据。

需要解释的是我水平有限，用VB强行结束服务进程有点勉强，在崔成龙大哥的提醒下想到了用DOS结束，方便（只需进程名就可以）、快捷、利索！不得不说，DOS的效率还是很高的！应该适当考虑！

说明：本来只是为了给米老师点击博客，但发现了一个共同的内存问题，我想有必要分享我的方法，互相交流，给需要的人以借鉴。

原创方法，转载注明出处！谢谢！

指导教师：米新江

主程序源码：

Option Explicit
Private Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Dim DatStart As Date   '记录开始时间

Private Sub Command1_Click()

SaveSetting "刷米老师博客", "URL", "URLKEY", Text1.Text     '存储目标网址
SaveSetting "刷米老师博客", "URL", "OUTURLKEY", Text4.Text   '存储跳出网址
SaveSetting "刷米老师博客", "Label", "LabelKey", Text3.Text     '存储目标行号

SaveSetting "刷米老师博客", "CMD", "CMDKey", "1"        '存储命令1，通知服务程序执行，其实直接关闭服务进程更好！但感觉用注册表是一种思想！
Shell App.Path & "\serve.exe"          '运行服务程序

End Sub

Private Sub Command2_Click()

SaveSetting "刷米老师博客", "CMD", "CMDKey", "0"      '存储命令2，通知服务程序终止

End Sub

Private Sub Command3_Click()

Dim I As Long

'输入有效性检验

If Text1.Text = "" Then
    MsgBox "目标网址为空！"
    Exit Sub
End If

If Text2.Text = "" Then
    MsgBox "关键字为空！"
    Exit Sub
End If

WebBrowser1.Navigate Text1.Text   '打开目标网页
WebBrowser1.Silent = True          '防止意外提示使控件挂起

'检测网页是否加载完毕

If WebBrowser1.Busy Then
    MsgBox "正在打开网页！可能是您的网速慢！"
    Exit Sub
End If

List1.Clear

Do While WebBrowser1.ReadyState <> READYSTATE_COMPLETE
    DoEvents
Loop

'遍历网页

For I = 1 To WebBrowser1.Document.All.Length - 1
    If InStr(1, WebBrowser1.Document.All(I).outerhtml, Text2.Text) > 0 Then  '查找关键字
        If UCase(WebBrowser1.Document.All(I).tagName) = "A" Then              '开头是大写A的说明是超链接，必须大写A
            List1.AddItem "第" & (List1.ListCount + 1) & "次出现的行号是" & I    '添加到列表中
        End If
    End If
Next

'检测关键字是否找到

If List1.ListCount = 0 Then
    MsgBox "关键字不存在！请确认输入正确！"
Else
    MsgBox "请根据实际情况填入行号，软件根据行号确定字符的位置！"
End If

End Sub

Private Sub Command4_Click()

'让用户确认是否为期望的网页

MsgBox "注意，程序将点击一次你所期望的链接，如果弹出的网页正确，请把弹出网页的的网址填入下边"

WebBrowser1.Document.All(Text3.Text).Click

End Sub

Private Sub Form_Load()

DatStart = Time    '记录一个开始时间

SaveSetting "刷米老师博客", "CountAll", "CountAllKey", "0"  '初始化已刷次数0

'在当前目录下建立一个批处理文件，用于杀服务进程

Open App.Path & "\files.bat" For Output As #1
    Print #1, "TASKKILL /F /IM serve.exe /T"
Close #1

End Sub


Private Sub Form_Unload(Cancel As Integer)

DeleteSetting "刷米老师博客"       '删除注册表项
Shell App.Path & "\files.bat"      '杀掉残余服务进程，清理内存

End Sub

Private Sub Timer1_Timer()

Label2.Caption = GetSetting("刷米老师博客", "CountAll", "CountAllKey")    '显示已刷次数
                 
End Sub

Private Sub Timer2_Timer()

'检测时间是否超过规定时间，如果超过，重启服务进程

If DateDiff("s", DatStart, Time) > 30 Then

     DatStart = Time
     
     Shell App.Path & "\files.bat"
     
     DoEvents
     Sleep 1500
     
     Shell App.Path & "\serve.exe"
     
End If

End Sub

服务程序源码：

Option Explicit
Dim lngnumber As Long    '记录已刷次数

Private Sub Form_Load()

'根据主程序对网页进行处理

WebBrowser1.Navigate GetSetting("刷米老师博客", "URL", "URLKEY")
WebBrowser1.Silent = True

While WebBrowser1.Busy
 DoEvents
Wend

End Sub

Private Sub Timer1_Timer()

On Error Resume Next   '错误处理，让程序保持安静

WebBrowser1.Document.All(Val(GetSetting("刷米老师博客", "Label", "LabelKey"))).Click   '根据主程序的参数点击相应的连接

End Sub

Private Sub Timer2_Timer()

If WebBrowser1.LocationURL = Trim(GetSetting("刷米老师博客", "URL", "OUTURLKEY")) Then Unload Me     '关闭点击连接弹出的连接

'判断主程序的运行命令

If GetSetting("刷米老师博客", "CMD", "CMDKey") = "0" Then
    Timer1.Enabled = False
ElseIf GetSetting("刷米老师博客", "CMD", "CMDKey") = "1" Then
    If Timer1.Enabled = False Then            '防止无谓的更改timer的属性，引起混乱
        Timer1.Enabled = True
    End If
End If

End Sub

 

Private Sub WebBrowser1_NewWindow2(ppDisp As Object, Cancel As Boolean)

'解释一下为什么记录已刷次数放这个事件里，因为只有这个事件被激活，才说明网页点击成功！这样计数比放在timer里准确！

lngnumber = Val(GetSetting("刷米老师博客", "CountAll", "CountAllKey")) + 1      '取上一次的已刷记录+1，防止服务端程序重新启动时计数清0

SaveSetting "刷米老师博客", "CountAll", "CountAllKey", Str(lngnumber)        '向主程序传递已刷次数

'防止网页跳出程序

Dim frmWB As Form1
Set frmWB = New Form1

frmWB.WebBrowser1.RegisterAsBrowser = True
Set ppDisp = frmWB.WebBrowser1.Object
'frmWB.Visible = True

End Sub